// group / version / java / repositories kommen vom Root-Build.
plugins {
    id 'application'
}

application {
    mainClass = 'de.blight.game.BlightApp'
    applicationDefaultJvmArgs = [
        '--add-opens', 'java.base/java.lang=ALL-UNNAMED',
        '--add-opens', 'java.desktop/sun.awt=ALL-UNNAMED',
        "-Djava.library.path=${buildDir}/natives"
    ]
}

ext {
    jmeVersion = '3.7.0-stable'
}

dependencies {
    implementation project(':blight-common')
    implementation project(':blight-assets')

    implementation "org.jmonkeyengine:jme3-core:${jmeVersion}"
    implementation "org.jmonkeyengine:jme3-desktop:${jmeVersion}"
    implementation "org.jmonkeyengine:jme3-lwjgl3:${jmeVersion}"
    implementation "org.jmonkeyengine:jme3-terrain:${jmeVersion}"
    implementation "org.jmonkeyengine:jme3-effects:${jmeVersion}"
    implementation "org.jmonkeyengine:jme3-jbullet:${jmeVersion}"
    implementation "org.jmonkeyengine:jme3-testdata:${jmeVersion}"
    implementation 'com.google.code.gson:gson:2.11.0'
}

tasks.register('extractNatives', Copy) {
    def nativeConf = configurations.runtimeClasspath.resolvedConfiguration
        .resolvedArtifacts
        .findAll { it.name.contains('natives') }
        .collect { zipTree(it.file) }

    from nativeConf
    into "${buildDir}/natives"
    duplicatesStrategy = DuplicatesStrategy.INCLUDE
}

run {
    dependsOn extractNatives
    workingDir = rootDir   // gemeinsames Arbeitsverzeichnis = Projekt-Root
}

jar {
    manifest {
        attributes 'Main-Class': application.mainClass
    }
}