plugins {
    id 'java'
}

ext {
    jmeVersion    = '3.9.0-stable'
    mainClassName = 'de.blight.fbxtest.FbxTestApp'
}

dependencies {
    implementation "org.jmonkeyengine:jme3-core:${jmeVersion}"
    implementation "org.jmonkeyengine:jme3-desktop:${jmeVersion}"
    implementation "org.jmonkeyengine:jme3-lwjgl3:${jmeVersion}"
    implementation "org.jmonkeyengine:jme3-plugins:${jmeVersion}"
    implementation 'com.github.stephengold:MonkeyWrench:1.0.0'
    runtimeOnly    'ch.qos.logback:logback-classic:1.5.18'
    implementation 'org.slf4j:slf4j-api:2.0.17'
}

tasks.register('extractNatives', Copy) {
    def nativeConf = configurations.runtimeClasspath.resolvedConfiguration
        .resolvedArtifacts
        .findAll { it.name.contains('natives') }
        .collect { zipTree(it.file) }
    from nativeConf
    into "${buildDir}/natives"
    duplicatesStrategy = DuplicatesStrategy.INCLUDE
}

tasks.register('run', JavaExec) {
    group       = 'application'
    description = 'Startet den FBX-Tester'
    mainClass   = mainClassName
    classpath   = sourceSets.main.runtimeClasspath
    javaLauncher = javaToolchains.launcherFor {
        languageVersion = JavaLanguageVersion.of(26)
    }
    jvmArgs = [
        '--add-opens', 'java.base/java.lang=ALL-UNNAMED',
        '--add-opens', 'java.desktop/sun.awt=ALL-UNNAMED',
        '--enable-native-access=ALL-UNNAMED',
        "-Djava.library.path=${buildDir}/natives",
    ]
    dependsOn extractNatives
    workingDir = rootDir
}