Commit

blight-fbx-test/build.gradle

@@ -0,0 +1,46 @@
+plugins {
+    id 'java'
+}
+
+ext {
+    jmeVersion    = '3.9.0-stable'
+    mainClassName = 'de.blight.fbxtest.FbxTestApp'
+}
+
+dependencies {
+    implementation "org.jmonkeyengine:jme3-core:${jmeVersion}"
+    implementation "org.jmonkeyengine:jme3-desktop:${jmeVersion}"
+    implementation "org.jmonkeyengine:jme3-lwjgl3:${jmeVersion}"
+    implementation "org.jmonkeyengine:jme3-plugins:${jmeVersion}"
+    implementation 'com.github.stephengold:MonkeyWrench:1.0.0'
+    runtimeOnly    'ch.qos.logback:logback-classic:1.5.18'
+    implementation 'org.slf4j:slf4j-api:2.0.17'
+}
+
+tasks.register('extractNatives', Copy) {
+    def nativeConf = configurations.runtimeClasspath.resolvedConfiguration
+        .resolvedArtifacts
+        .findAll { it.name.contains('natives') }
+        .collect { zipTree(it.file) }
+    from nativeConf
+    into "${buildDir}/natives"
+    duplicatesStrategy = DuplicatesStrategy.INCLUDE
+}
+
+tasks.register('run', JavaExec) {
+    group       = 'application'
+    description = 'Startet den FBX-Tester'
+    mainClass   = mainClassName
+    classpath   = sourceSets.main.runtimeClasspath
+    javaLauncher = javaToolchains.launcherFor {
+        languageVersion = JavaLanguageVersion.of(26)
+    }
+    jvmArgs = [
+        '--add-opens', 'java.base/java.lang=ALL-UNNAMED',
+        '--add-opens', 'java.desktop/sun.awt=ALL-UNNAMED',
+        '--enable-native-access=ALL-UNNAMED',
+        "-Djava.library.path=${buildDir}/natives",
+    ]
+    dependsOn extractNatives
+    workingDir = rootDir
+}

blight-fbx-test/src/main/resources/logback.xml

@@ -0,0 +1,12 @@
+<configuration>
+    <appender name="CONSOLE" class="ch.qos.logback.core.ConsoleAppender">
+        <encoder>
+            <pattern>%d{HH:mm:ss} %-5level [%logger{20}] %msg%n</pattern>
+        </encoder>
+    </appender>
+    <root level="INFO">
+        <appender-ref ref="CONSOLE"/>
+    </root>
+    <logger name="com.jme3" level="WARN"/>
+    <logger name="com.github.stephengold" level="INFO"/>
+</configuration>

settings.gradle

@@ -7,3 +7,4 @@ include 'blight-lang'
 include 'blight-editor'
 include 'blight-game'
 include 'blight-vegetation-generator'
+include 'blight-fbx-test'